Fake Specular 만들기

 

Shader "Custom/BlinnPhong2"
{
    Properties
    {
      
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
        _SpecColor("SpecColor",Color)=(1,1,1,1)
        _BumpMap("Normalmap",2D) ="bump"{}
        _Gloss("Gloss",2D)="white" {}
        _RimColor("RimColor",Color)=(1,1,1,1)
        _FakeSpecColor("FakeSpecColor",Color)=(1,1,1,1)

    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
       

        CGPROGRAM
       
        #pragma surface surf _Phong noambient

        
        #pragma target 3.0

        sampler2D _MainTex;
        sampler2D _BumpMap;
        sampler2D _Gloss;
        float4 _RimColor;
        float4 _FakeSpecColor;

        struct Input
        {
            float2 uv_MainTex;
            float2 uv_Gloss;

        };

        struct SurfaceOutputCustom        
        {
            fixed3 Albedo;
            fixed3 Normal;
            fixed3 Emission;
            half Specular;
            half Gloss;
            fixed Alpha;
            float CustomData;

        };

        

        void surf (Input IN, inout SurfaceOutputCustom o)
        {
          
            float4 c = tex2D (_MainTex, IN.uv_MainTex);
            // 노멀맵
            fixed4 n =tex2D(_BumpMap,IN.uv_MainTex);            
            o.Normal  =UnpackNormal(n);

            float4 d = tex2D (_Gloss, IN.uv_Gloss);
            o.Gloss = d.a;


            o.Albedo = c.rgb;           
            o.Alpha = c.a;
        }

        float4 Lighting_Phong(SurfaceOutputCustom s, float3 lightDir, float3 viewDir,float atten)
        {
            

             //Lambert 라이트 diffuse N L
             
             float3 diffuseColor;
             float ndotl =saturate(dot(s.Normal,lightDir)); //0~1                           
             diffuseColor = ndotl*s.Albedo*_LightColor0.rgb*atten;


             // BlinnPhong 라이트 spec 
             float3 specColor;
             float3 h = normalize(lightDir+viewDir); //하프 단위 벡터 구하기
             float spec =saturate(dot(h,s.Normal));//스펙튤러 구하기/ 제일 밝음
             specColor = pow(spec,100) * _SpecColor.rgb * s.Gloss;

             // Rim 라이트
             float3 rimColor;
             float rim =abs(dot(viewDir,s.Normal));
              //rimColor = pow(rim,6)*_RimColor;             
             float invertRim =1-rim; //반전
             rimColor = pow(invertRim,6)*_RimColor; // 제곱으로 빛의 양 조절


             //fake spec
             float3 fakeSpecColor;
             fakeSpecColor =  pow(rim,50)*_FakeSpecColor*s.Gloss; 



             //final 적용
            float4 final;
            final.rgb= diffuseColor+specColor+rimColor+fakeSpecColor;//
            final.a =s.Alpha;

            return final;
         }



        ENDCG
    }
    FallBack "Diffuse"
}